WiserBit

Option Explicit
 
Private Sub cmdATCommand_Click()
 
'Write data to serial port.

Dim lngSize     As Integer
Dim strData     As String
Dim lngStatus   As Long
 
'Get the command:
strData = txtATCommand.Text & vbCr
 
'Get the size:
lngSize = Len(strData)
 
'Write the data:
lngStatus = cComm1.CommWrite(strData)
 
'Handle error.
If lngStatus <> lngSize Then
    'Error..
End If
 
End Sub
 
Private Sub cmdConfig_Click()
 
'Display configuration:

Dim lErr As Long
 
lErr = cComm1.LineConfigDialog(Combo1.ListIndex)
If lErr <> 0 Then
    'Err
End If
 
End Sub
 
Private Sub cmdLineInfo_Click()
 
Dim LineDev As LineDevCap
 
'Set the line index to get the results for:
cComm1.LineIndex = Combo1.ListIndex
 
'Get the device index to the LineDev:
cComm1.LineGetDevDetails LineDev
 
'Display the results:
txtResults = vbCrLf _
            & "Device Name:" & LineDev.DeviceName & vbCrLf _
            & "Tapi Capability: " & LineDev.TapiCapability & vbCrLf _
            & "Max Rate: " & LineDev.MaxRate & vbCrLf _
            & "Support Monitor Digits: " & LineDev.MonitorDigits & vbCrLf _
            & "Support Generate Digits: " & LineDev.GenerateDigits & vbCrLf _
            & "Data Mode:" & LineDev.MediaDatamodem & vbCrLf _
            & "Interactivevoice:" & LineDev.MediaInteractivevoice & vbCrLf _
            & "Auto Voice:" & LineDev.MediaAutomatedvoice & vbCrLf _
            & "Comm Port:" & cComm1.GetPortNumber(Combo1.ListIndex) & vbCrLf
 
            txtResults = txtResults & vbCrLf
 
End Sub
 
Private Sub cmdLocInfo_Click()
 
'Get the country code:
txtResults.Text = txtResults & "Local country Code:" & cComm1.GetCountryCode & vbCrLf
 
'Get the city code:
txtResults.Text = txtResults & "Local city Code:" & cComm1.GetCityCode & vbCrLf
 
End Sub
 
 
Private Sub cmdLocProp_Click()
 
cComm1.LineTranslateDialog
 
End Sub
 
 
Private Sub cmdOff_Click()
 
Dim rc As Long
 
'Close the comm port
rc = cComm1.CommClose
 
If rc = 0 Then
    cmdOff.Enabled = False
    cmdATCommand.Enabled = False
    cmdOn.Enabled = True
End If
 
 
End Sub
 
 
Private Sub cmdOn_Click()
 
    Dim lPort As Integer
    Dim rc As Long
 
    'First, get the port number of the device:
    lPort = cComm1.GetPortNumber(Combo1.ListIndex)
    If lPort < 0 Then
        'Error
        Exit Sub
    End If
 
    'Set the port number:
    cComm1.Port = lPort
 
    'Open the comm port
    rc = cComm1.CommOpen("COM" & CStr(lPort), txtSetting.Text)
 
    If rc = 0 Then
        cmdOff.Enabled = True
        cmdATCommand.Enabled = True
        cmdOn.Enabled = False
    End If
 
End Sub
 
Private Sub Form_Load()
 
'Init the control, must be call
'before using any functionality
'of the control.
'
'sKey = Your license key.
'
cComm1.Init "Trial Mode."
 
Dim LineIndex As Long
Dim sDeviceName As String
Dim LineDev As LineDevCap
 
 
'Scan all the lines and get the device name:
For LineIndex = 0 To cComm1.NumOfLines - 1
 
    'Get device details by the index
    cComm1.LineIndex = LineIndex
    cComm1.LineGetDevDetails LineDev
    sDeviceName = LineDev.DeviceName
 
    'Add to the list DeviceName and DeviceIndex.
    Combo1.AddItem sDeviceName
 
Next LineIndex
 
Combo1.ListIndex = 0
 
 
End Sub
 
Private Sub Form_Unload(Cancel As Integer)
 
cComm1.CommClose
 
'Release the control
cComm1.DeInit
 
End Sub
 
Private Sub txtResults_Change()
 
'Auto scroll down:
txtResults.SelStart = Len(txtResults.Text) - 1
 
End Sub
 
 
'*******************************************************
'   Events:
'*******************************************************

Private Sub cComm1_CommEvent(sMessage As String)
 
txtResults.Text = txtResults.Text & sMessage & vbCrLf
 
End Sub
 
Private Sub cComm1_Error(lErrNumber As Long, sErrMessage As String)
 
MsgBox sErrMessage
 
End Sub